2025/7/18

複数条件付きで合計する関数の違い(SUMIF, SUMIFS, DSUM, SUMPRODUCTなど)【エクセル】

はじめに

エクセルには数値を合計する関数が多くあります。その中で、条件指定が可能な関数の違いについてまとめました。

ここでは、以下について取り扱います：

関数の比較
AND条件の設定例
OR条件の設定例
細かな違い（セルの認識、判定・条件分岐関数の組込み）
使い分けの目安

関数の比較表

条件を指定して合計する関数の一覧を、下の表にまとめました。

各関数の使用例はAND条件の設定例 (後述) にあります。

関数名	条件設定の形式	複数条件の設定 (AND条件)	(OR条件)	判定・条件分岐関数の組込み	エラー値の扱い ※2	あいまい検索 (ワイルドカード)	備考	対応バージョン
`SUMIF`	文字列	❌ 不可	🟡 一部可能 ※1	❌ 不可	✅ 条件と比較可	✅ 使用可	単一条件のみ	全バージョン
`SUMIFS`	文字列	✅ 可能	🟡 一部可能 ※1	❌ 不可	✅ 条件と比較可	✅ 使用可	複数条件可	全バージョン

`DSUM`	データベース	✅ 可能	✅ 可能	❌ 不可	✅ 条件と比較可	✅ 使用可	数値のみを合計 + 設定条件でフィルタ	全バージョン

`SUMPRODUCT`	配列演算	✅ 可能	✅ 可能	✅ 可能	🟡 エラーを出力	❌ 使用不可	慣れが必要	全バージョン
`FILTER`+`SUM`	配列演算	✅ 可能	✅ 可能	✅ 可能	🟡 エラーを出力	❌ 使用不可	可読性・再利用性が高い	2021, 365 ~

※1 関数を複数回使用することで対応可能（ただしSUMIFのみでは「 重複あり のOR条件」は不可）

※2 詳細は後述

AND条件の設定例

それぞれの関数を使って、 ANDの複数条件を設定した例を下記に示します。複数条件の設定の基本形となります。

「(合計されるセルを個別選択)」列のセルをホバーすると、合計されているセルがハイライトされます。

計算値を表示

	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1	カテゴリ	ランク	数値					条件1		条件2
2	A	1	100				関数名	(カテゴリ)		(ランク)		数値の合計		(合計されるセルを個別選択)
3	A	2	100				SUMIF関数	<>A				500		500
4	B	1	100				SUMIFS関数	<>A		>=2		300		300
5	B	2	100
6	C	1	100				DSUM関数	カテゴリ		ランク		300		300
7	C	2	100					<>A		>=2
8	C	3	100
9							SUMPRODUCT関数	A	でない	2	以上	300		300
10							FILTER+SUM	A	でない	2	以上	300		300

数式の例

関数条件設定の形式数式の例備考
SUMIF 文字列 =SUMIF(A2:A8, "<>A", C2:C8) AND条件の設定は不可
SUMIFS =SUMIFS(C2:C8, A2:A8,"<>A", B2:B8, ">2") -
DSUM データベース =DSUM( A1:B8,1, G6:I7 )
SUMPRODUCT 配列演算 =SUMPRODUCT((A2:A8<>"A") * (B2:B8>=2) * C2:C8)
FILTER+SUM =SUM( FILTER( C2:C8, (A2:A8<>"A") * (B2:B8>=2) ))

関数	条件設定の形式	数式の例	備考
`SUMIF`	文字列	=`SUMIF`(A2:A8, "<>A", C2:C8)	AND条件の設定は不可
`SUMIFS`	=`SUMIFS`(C2:C8, A2:A8,"<>A", B2:B8, ">2")	-
`DSUM`	データベース	=`DSUM`( A1:B8,1, G6:I7 )
`SUMPRODUCT`	配列演算	=`SUMPRODUCT`(*(A2:A8<>"A") (B2:B8>=2)** * C2:C8)
`FILTER`+`SUM`	=`SUM`( `FILTER`( C2:C8, *(A2:A8<>"A") (B2:B8>=2)** ))

OR条件の設定例

OR条件では、条件の間に「重複がない場合」と「重複がある場合」によって書き方が変わります。

「重複がない / ある場合」とは、「OR条件を同時に満たすことがない / ある場合」のことです。
例：

重複の有無	OR条件の例	OR条件を同時に満たす条件
重複がない場合	「1以下」OR「5以上」	「1以下かつ5以上」→ 存在しない
重複がある場合	「1以上」OR「5以下」	「1以上かつ5以下」→ 存在する（1, 2, 3, 4, 5など）

2つの条件に重複がない場合

重複のないOR条件を設定した合計する関数の使用例を示します。設定条件は「カテゴリがCでない」OR「ランクが2越え」です（「カテゴリがCでない」かつ「ランクが2越え」は存在しないため、重複のない場合に相当）。 SUMIF関数については省略しています。

「(合計されるセルを個別選択)」列のセルをホバーすると、合計されているセルがハイライトされます。

計算値を表示

	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1	カテゴリ	ランク	数値					条件1		条件2
2	A	1	100				関数名	(カテゴリ)		(ランク)		数値の合計		(合計されるセルを個別選択)
3	A	2	100				SUMIFS関数	<>C		>2		500		500
4	B	1	100
5	B	2	100				DSUM関数	カテゴリ		ランク		500		500
6	C	1	100					<>C
7	C	2	100							>2
8	C	3	100
9							SUMPRODUCT関数	C	でない	2	越え	500		500
10							FILTER+SUM	C	でない	2	越え	500		500

数式の例

関数条件設定の形式数式の例備考
SUMIFS 文字列 =SUMIFS( C2:C8, A2:A8, "<>C" ) + SUMIFS( C2:C8, B2:B8, ">2") 関数を複数回使用
(各条件ごとに合計)
DSUM データベース =DSUM( A1:C8, 3, H5:J7 ) -
SUMPRODUCT 配列演算 =SUMPRODUCT( ((A2:A8<>"C") + (B2:B8>2) ) * C2:C8 )
FILTER+SUM =SUM( FILTER( C2:C8, (A2:A8<>"C") + (B2:B8>2) ))

関数	条件設定の形式	数式の例	備考
`SUMIFS`	文字列	=`SUMIFS`( C2:C8, A2:A8, "<>C" ) + `SUMIFS`( C2:C8, B2:B8, ">2")	関数を複数回使用 (各条件ごとに合計)
`DSUM`	データベース	=`DSUM`( A1:C8, 3, H5:J7 )	-
`SUMPRODUCT`	配列演算	=`SUMPRODUCT`( ((A2:A8<>"C") + (B2:B8>2) ) * C2:C8 )
`FILTER`+`SUM`	=`SUM`( `FILTER`( C2:C8, (A2:A8<>"C") + (B2:B8>2) ))

2つの条件に重複がある場合

重複のあるOR条件を設定した合計する関数の使用例を示します。設定条件は「カテゴリがCでない」OR「ランクが2未満」です（「カテゴリがCでない」かつ「ランクが2未満」が存在する（例：「カテゴリがA」かつ「ランクが1」など）ため重複のある場合に相当）。

SUMIF関数については省略しています。

「(合計されるセルを個別選択)」列のセルをホバーすると、合計されているセルがハイライトされます。

計算値を表示

	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1	カテゴリ	ランク	数値					条件1		条件2
2	A	1	100				関数名	(カテゴリ)		(ランク)		数値の合計		(合計されるセルを個別選択)
3	A	2	100				SUMIFS関数	<>C		<2		500		500
4	B	1	100
5	B	2	100				DSUM関数	カテゴリ		ランク		500		500
6	C	1	100					<>C
7	C	2	100							<2
8	C	3	100
9							SUMPRODUCT関数	C	でない	2	未満	500		500
10							FILTER+SUM	C	でない	2	未満	500		500

数式の例

関数条件設定の形式数式の例備考
SUMIFS 文字列 =SUMIFS(C2:C8, A2:A8, "<>C") + SUMIFS(C2:C8, B2:B8, "<2") - SUMIFS(C2:C8, A2:A8, "<>C", B2:B8, "<2" ) 関数を複数回使用
(各条件の和 - 重複分)
DSUM データベース =DSUM(A1:C8, 3, H5:J7) -
SUMPRODUCT 配列演算 =SUMPRODUCT( ( (A2:A8<>"C") + (B2:B8<2) - (A2:A8<>"C") * (B2:B8<2) ) * C2:C8 )
FILTER+SUM =SUM( FILTER( C2:C8, (A2:A8<>"C") + (B2:B8<2) - (A2:A8<>"C") * (B2:B8<2) ) )

関数	条件設定の形式	数式の例	備考
`SUMIFS`	文字列	=`SUMIFS`(C2:C8, A2:A8, "<>C") + `SUMIFS`(C2:C8, B2:B8, "<2") - `SUMIFS`(C2:C8, A2:A8, "<>C", B2:B8, "<2" )	関数を複数回使用 (各条件の和 - 重複分)
`DSUM`	データベース	=`DSUM`(A1:C8, 3, H5:J7)	-
`SUMPRODUCT`	配列演算	=`SUMPRODUCT`( ( *(A2:A8<>"C") + (B2:B8<2) - (A2:A8<>"C") (B2:B8<2)** ) * C2:C8 )
`FILTER`+`SUM`	=`SUM`( `FILTER`( C2:C8, *(A2:A8<>"C") + (B2:B8<2) - (A2:A8<>"C") (B2:B8<2)** ) )

細かな挙動の違いと関数の組込み

条件指定が可能な合計値の算出関数は、空白（空白セル、空文字）やエラー値を含むセルに対する応答が異なる場合があります。

また、条件指定の中で、 IF関数グループやIS関数グループなどの判定・条件分岐関数を組み込みたい場合は、 SUMPRODUCT / FILTER+SUM関数以外では使えません。

空白やエラー値を含むときの挙動の違い

ほとんどの関数は、条件の判定値の中に空白セル、空文字、エラー値が入っていても、条件と比較して判定が可能です (例：「"A"でない」の条件設定で空文字をマッチできる) 。ただし、 SUMPRODUCTとFILTER+SUM関数は、エラー値を参照するとエラー値を返すので注意が必要です。

「(合計されるセルを個別選択)」列のセルをホバーすると、合計されているセルがハイライトされます。

計算値を表示

	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1	カテゴリ	ランク	数値					条件1		条件2
2	A	1	100				関数名	(カテゴリ)		(ランク)		数値の合計		(合計されるセルを個別選択)
3	A	2	100				SUMIFS関数	<>A		>=2		400		400
4	B	1	100
5	B	2	100				DSUM関数	カテゴリ		ランク		400		400
6		2	100					<>A		>=2
7		2	100
8	#N/A	2	100				SUMPRODUCT関数	A	でない	2	以上	#N/A		#N/A
9							FILTER+SUM	A	でない	2	以上	#N/A		#N/A

各関数ごとの、条件の 判定値の中 と 合計する値の中 での 空白セル, 空文字, エラー値 の扱いをまとめると、以下の通りです。

関数	`空白セル`の扱い	`空文字`の扱い	`エラー値`の扱い	備考
`SUMIF`	判定値の中： ✅条件と比較可合計する値の中： ⏭️無視	判定値の中： ✅条件と比較可合計する値の中： ⏭️無視	判定値の中： ✅条件と比較可合計する値の中：🟡エラーを出力	-
`SUMIFS`
`DSUM`
`SUMPRODUCT`		判定値の中： ✅条件と比較可合計する値の中： 🟡エラーを出力	🟡エラーを出力	`IFERROR`関数の組込みでエラー回避可能
`FILTER`+`SUM`		判定値の中： ✅条件と比較可合計する値の中： ⏭️無視	🟡エラーを出力	`IFERROR`関数の組込みでエラー回避可能

条件分岐関数を組み込んだ例

SUMPRODUCTとFILTER+SUM関数は、判定や条件分岐を行う関数が組み込めます。ここでは、IFERROR関数を使い、エラー値を無視するようにした例を示します。

「(合計されるセルを個別選択)」列のセルをホバーすると、合計されているセルがハイライトされます。

計算値を表示

	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1	カテゴリ	ランク	数値					条件1		条件2
2	A	1	100				関数名	(カテゴリ)		(ランク)		数値の合計		(合計されるセルを個別選択)
3	A	2	100				SUMPRODUCT関数	A	でない	2	以上	#N/A		#N/A
4	B	1	100									↓
5	B	2	100				＋IFERROR関数					300		300
6		2	100
7		2	100
8	#N/A	2	100				FILTER+SUM	A	でない	2	以上	#N/A		#N/A
9												↓
10							＋IFERROR関数					300		300

数式の例

関数条件設定の形式数式の例
SUMPRODUCT 配列演算 =SUMPRODUCT(
IFERROR((A2:A8<>"A")*(B2:B8>=2) * C2:C8, 0)
)
FILTER+SUM =SUM( FILTER(C2:C8,
IFERROR( (A2:A8<>"A")*(B2:B8>=2), FALSE)
))

関数	条件設定の形式	数式の例
`SUMPRODUCT`	配列演算	=`SUMPRODUCT`( `IFERROR`(*(A2:A8<>"A")(B2:B8>=2)** * C2:C8, 0) )
`FILTER`+`SUM`	=`SUM`( `FILTER`(C2:C8, `IFERROR`( *(A2:A8<>"A")(B2:B8>=2)**, FALSE) ))

使い分けの目安

条件指定が可能な合計する関数の使い分けの目安は、以下の通りです。

単純な条件 / AND条件のとき SUMIFS関数 (SUMIF関数)
データベース形式で条件設定 / OR条件のとき DSUM関数
複雑な条件 / 判定・条件分岐関数を組み込むとき SUMPRODUCT / FILTER+SUM関数